home *** CD-ROM | disk | FTP | other *** search
/ TPUG - Toronto PET Users Group / TPUG Users Group CD / TPUG Users Group CD.iso / NEW / A-Newest / TORPET.d64 / menu select.2 (.txt) < prev    next >
Commodore BASIC  |  2009-10-12  |  2KB  |  50 lines
  1. 100 REM MENU SELECTION WITH JOYSTICK
  2. 110 REM DISPLAY MENU WITH CURSOR
  3. 120 L=1510:V=0
  4. 130 POKE53281,0:PRINT"[147][144]SAMPLE MENU :":POKE53281,1:POKE L,81
  5. 140 PRINT"USE JOYSTICK TO CHOOSE LINE"
  6. 150 PRINT"THEN PRESS BUTTON TO SELECT"
  7. 160 PRINT"PAYROLLL PROGRAM"
  8. 170 PRINT"ACCOUNTS PAYABLE PROGRAM"
  9. 180 PRINT"ACCOUNTS RECEIVABLE"
  10. 190 PRINT"INVENTORY PROGRAM"
  11. 200 PRINT"STOCKHOLDER RECORDS"
  12. 210 PRINT"STOP RUN"
  13. 220 GOSUB 350:REM CHECK JOYSTICK AND BUTTON
  14. 230 REM SEE IF BUTTON WAS PRESSED
  15. 240 IF FB=0 THEN 460
  16. 250 REM IF JOYSTICK NOT UP OR DOWN
  17. 260 REM AND FIRE BUTTON WAS NOT PRESSED,
  18. 270 REM GO BACK TO SCAN KEYBOARD
  19. 280 REM CHECK FOR JOYSTICK UP
  20. 290 IF JD=1 THEN IF V>4 THEN 220
  21. 300 IF JD=1 THEN V=V+3:POKE L,96:L=L-120:POKE L,81:FOR I=1TO250:NEXTI:GOTO 220
  22. 310 REM CHECK FOR JOYSTICK DOWN
  23. 320 IF JD=2 THEN IF V<-7 THEN 220
  24. 330 IF JD=2 THEN V=V-3:POKE L,96:L=L+120:POKE L,81:FOR I=1TO250:NEXTI:GOTO 220
  25. 340 GOTO 220:REM GO BACK TO CHECK FOR JOYSTICK
  26. 350 REM CHECK FOR FIREBUTTON PRESSED
  27. 360 REM AND TO FIND JOYSTICK DIRECTION
  28. 370 REM FB IS FIREBUTTON VALUE
  29. 380 REM FB=0 IF PRESSED
  30. 390 REM FB=16 IF NOT PRESSED
  31. 400 JV=PEEK(56321)
  32. 410 FB=JV AND 16
  33. 420 JD=15-(JV AND 15)
  34. 430 REM JD=1 IF JOYSTICK UP
  35. 440 REM JD=2 IF JOYSTICK DOWN
  36. 450 RETURN
  37. 460 REM HERE IS WHERE YOU GO IF BUTTON IS PRESSED
  38. 470 FOR I=1 TO 250:NEXT I
  39. 480 IF V=6 THEN PRINT"[147]PAYROLL PROGRAM SELECTED":GOTO 540
  40. 490 IF V=3 THEN PRINT"[147]ACCOUNTS PAYABLE SELECTED":GOTO 540
  41. 500 IF V=0 THEN PRINT"[147]ACCOUNTS RECEIVABLE SELECTED":GOTO 540
  42. 510 IF V=-3 THEN PRINT"[147]INVENTORY PROGRAM SELECTED":GOTO 540
  43. 520 IF V=-6 THEN PRINT"[147]STOCKHOLDER RECORD PROGRAM":GOTO 540
  44. 530 IF V=-9 THEN PRINT"[147]END OF RUN":STOP
  45. 540 PRINT"PRESS BUTTON TO RETURN TO MAIN MENU"
  46. 550 REM WAIT HERE UNTIL BUTTON IS PRESSED
  47. 560 A=PEEK(56321) AND 16
  48. 570 IF A<>0 THEN 560
  49. 580 FOR I=1 TO 250:NEXT I:GOTO 130
  50.